{ inputs, ... }: {
  flake-file.inputs = {
    aghpb = {
      url = "github:cat-milk/Anime-Girls-Holding-Programming-Books";
      flake = false;
    };
    orly-covers = {
      url = "github:thepracticaldev/orly-full-res";
      flake = false;
    };
  };

  flake.modules.homeManager.randomized-aghpb-wallpaper = { pkgs, ... }:
    let
      combined_wallpapers = pkgs.symlinkJoin {
        name = "joined-wallpapers";
        paths = with inputs; [
          aghpb
          orly-covers
        ];
      };
    in
    {
      imports = with inputs.self.factory; [
        (wpaperd {
          default = {
            path = combined_wallpapers;
            recursive = true;
            mode = "stretch";
            duration = "5m";
          };
        })
      ];

      wayland.windowManager.hyprland.extraConfig = ''
        hl.bind("SUPER + i", hl.dsp.exec_cmd("${pkgs.unstable.wpaperd}/bin/wpaperctl next"))
        hl.bind("SUPER + o", hl.dsp.exec_cmd("${pkgs.unstable.wpaperd}/bin/wpaperctl set ${inputs.assets}/horizontal_16x9.png"))
      '';
    };
}
